1000 *--------------------------------
 1010 * PRIM... JUST JSR PRIM
 1020 * AND THEN PUT YOUR ASCII TO
 1030 * PRINT OUT AFTER THE JSR.
 1040 * ($60=FLASHING SPACE,$8D=RETURN)
 1050 * PUT A $00 AT THE END OF THE
 1060 * PRINTOUT, AND CONTROL WILL
 1070 * GO BACK TO RIGHT AFTER THE END
 1080 * OF THE DATA ($00)
 1090 *---------------------------------
 1100 COUT   .EQ $FDED
 1110 R15    .EQ $1E
 1120 SAVE   .EQ $FF4A
 1130 RESTORE .EQ $FF3F
 1135        .OR $800
 1140 START
 1150        JSR PRIM
 1160        .AS -"HI THERE!"
 1170        .HS 8D
 1180        .AS -"WELCOME TO THE TRACER DEMONSTRATOR!"
 1190        .HS 8D
 1200        .HS 8D
 1210        .AS -"YOU'RE ALREADY SEEING ONE ADVANTAGE"
 1220        .HS 8D
 1230        .AS -"OF THE TRACER - YOU CAN TRACE PROGRAMS"
 1240        .HS 8D
 1250        .AS -"WITH OUTPUT. NOT ALL TRACERS CAN DO"
 1260        .HS 8D
 1270        .AS -"THIS!"
 1280        .HS 8D
 1290        .HS 8D
 1300        .AS -"PRESS N TO SEE THE TRACER DISPLAY,"
 1310        .HS 8D
 1320        .AS -"AND V TO SEE THE VICTIM DISPLAY"
 1330        .HS 8D
 5990        .HS 00
 5995        BRK
 6000 PRIM
 6010        JSR SAVE
 6020        PLA
 6030        STA R15
 6040        PLA
 6050        STA R15+1
 6060        LDY #0
 6070 PRINTR15LOOP
 6080        JSR INCR15
 6090        LDA (R15),Y
 6100        BEQ DONEPRIM
 6110        JSR COUT
 6120        JMP PRINTR15LOOP
 6130 INCR15
 6140        INC R15
 6150        BNE .1
 6160        INC R15+1
 6170 .1     RTS
 6180 DONEPRIM
 6190        JSR INCR15
 6200        JSR RESTORE
 6210        JMP (R15)